@echo off
REM #########################################################
REM #
REM # Source: 600infos.de
REM # Vers. 2017-12-17a
REM #
REM #########################################################
:env
  color 1E
  
:vars
  set "_RegKey=DontUsePowerShellOnWinX"
  set "_RegPath=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
  set "_RegWord=1"
  set "_Key=1"
  
:start
  cls
  echo.
  echo.Ersetzt PowerShell mit Eingabeaufforderung im WinX-Menue
  echo.
  echo.  REG_DWORD    0x0 = Ausgeblendet = PowerShell
  echo.  REG_DWORD    0x1 = Eingeblendet = Eingabeaufforderung 
  REM.
  echo.
  echo.--- 
  echo.Aktueller Wert:
  REG QUERY "%_RegPath%"  /v %_RegKey%  
  echo.---  
  echo.
  echo.AUSWAHL:
  echo.
  echo. 0 = PowerShell
  echo. 1 = Eingabeaufforderung
  echo. e = Ende
  echo.
  set /p "_Key=Ihre Wahl: "
  if "%_Key%"=="0" call :choice0
  if "%_Key%"=="0" goto :start
  if "%_Key%"=="1" call :choice1
  if "%_Key%"=="1" goto :start
  if /I "%_Key%"=="e" goto :end
  echo.ERROR
  pause
  goto :start

:choice0
  REG ADD "%_RegPath%"  /v %_RegKey% /t REG_DWORD /d 0
  exit /b

:choice1
  REG ADD "%_RegPath%"  /v %_RegKey% /t REG_DWORD /d 1 
  exit /b

:end
  cls
  echo.
  echo.HINWEIS:
  echo.
  echo.Um die Aenderung aktiv werden zu lassen, 
  echo.muss man sich einmal abmelden und wieder anmelden.
  echo.
  timeout 10
  exit /b