@echo off
REM Version 2018-10
REM add -autoreconnect 
:: mark-hilft2.cmd
:settings
  set __URL__=Domain:5500
:check4exe 
  set __VNCpath__=C:\Program Files\uvnc bvba\UltraVNC
  if exist "%__VNCpath__%\winvnc.exe" goto check4service
  set __VNCpath__=C:\prg\UltraVNC
  if exist "%__VNCpath__%\winvnc.exe" goto check4service
  set __VNCpath__=D:\prg\UltraVNC
  if exist "%__VNCpath__%\winvnc.exe" goto check4service
  set __VNCpath__=C:\Programme\UltraVNC
  if exist "%__VNCpath__%\winvnc.exe" goto check4service
  set __VNCpath__=C:\Program Files (x86)
  if exist "%__VNCpath__%\winvnc.exe" goto check4service
  set __VNCpath__=%ProgramFiles%\uvnc bvba\UltraVNC
  if exist "%__VNCpath__%\winvnc.exe" goto check4service
  set __VNCpath__=%ProgramFiles(x86)%\uvnc bvba\UltraVNC
  if exist "%__VNCpath__%\winvnc.exe" goto check4service
  echo.
  echo.winvnc.exe not found.
  echo.please install uVNC
  echo.
  echo.press any key to quit
  pause > NUL
  goto end
:check4service
  ::if-vnc-is-running
  net start | find "uvnc_service" > NUL && goto connect || goto start
:start
  echo.uVNC wird gestartet...
  "%__VNCpath__%\winvnc.exe"
:connect
  echo.Verbindung zu %__URL__% wird hergestellt ...
  "%__VNCpath__%\winvnc.exe" -autoreconnect -connect %__URL__%
:end
  echo.