@echo off
REM ##############################################
REM 
REM script firewall.cmd
REM  create rules for ms firewall
REM
REM ##############################################

:check_admin
  cls
  cacls "%SYSTEMROOT%\system32\config\system" || (
    echo need Adminrights!
    goto end
  )
  cls

:global_vars
  set _appName=mySQL visualBIZZ
  set _appPort=3306

echo.%date% %time% *** Start script %~nx0% ***
echo.creating Firewall rules ...

:call_functions

  rem         action       direction  protocol  localport     remoteport
  rem addrule [allow/deny] [in/out]   [udp/tcp] [1-65535/any] [1-65535/any]
  rem 
  
  call :addrule allow out tcp any %_appPort% 
  call :addrule allow out udp any %_appPort% 
  call :addrule allow in tcp %_appPort% any
  call :addrule allow in udp %_appPort% any 


goto end

::functions
:addrule

  echo.|set /p x=erase rule if exist ... 
  netsh advfirewall firewall delete rule name=all dir=%~2 protocol=%~3 localport=%~4 remoteport=%~5 >nul 2>&1 && echo erased || echo ok

  echo.|set /p x=create rule for "%_appName%" %~1 %~2 %~3 local:%~4 destination:%~5 ...
  netsh advfirewall firewall add rule name="%_appName% %~3" dir=%~2 protocol=%~3 localport=%~4 remoteport=%~5 action=%~1

  exit /b

:end

echo.%date% %time% *** End script %~nx0% *** 
pause

echo.%date% %time% *** End script %~nx0% ***