@ECHO OFF
rem send-a-mail.cmd vers.0.0.1 26.11.2008 Mark Wolfgruber
rem send email from command line via SMTP with sendmail
rem using sendmail from: http://glob.com.au/sendmail
rem configure sendmail.ini before

set __sendmail__=%ProgramFiles%\sendmail\sendmail.exe -t
set __from__=%USERNAME%@%COMPUTERNAME%.%USERDOMAIN%
set __to__= name@domain.com
set __subject__=Mail %date% %time%
set __data__=Text
set __prefix__=sendmail_%date%_%time%
set "__prefix__=%__prefix__: =_%"
set "__prefix__=%__prefix__:,=_%"
set "__prefix__=%__prefix__:.=-%"
set "__prefix__=%__prefix__:/=-%"
set "__prefix__=%__prefix__::=-%"
set "__prefix__=%__prefix__:---=-%"
set "__prefix__=%__prefix__:--=-%"
set "__prefix__=%__prefix__:___=_%"
set "__prefix__=%__prefix__:__=_%"
set __temp__=%TEMP%\%__prefix__%
set __tempfile__=%__temp__%.tmp
set __textfile__=%__temp__%.txt

:input
cls
echo ### send-a-mail ###
echo.
set /P __from__=From [%__from__%]:
set /P __to__=To [%__to__%]:
set __cc__=%__from__%
set /P __cc__=Cc [%__cc__%]:
set /P __subject__=Subject [%__subject__%]:
echo Input a text and end with [F6] or [Strg]+[Z]
copy con %__textfile__%

:send_mail
call :create_mail
set __quest__=N
set /P __quest__=are you sure? [%__quest__%]:

if "%__quest__%"=="y" set __quest__=Y
if "%__quest__%"=="j" set __quest__=Y
if "%__quest__%"=="J" set __quest__=Y
if "%__quest__%"=="Y" %__sendmail__% < %__tempfile__%


:create_copy
set __quest__=N
set /P __quest__=do you want a copy? [%__quest__%]:

if "%__quest__%"=="y" set __quest__=Y
if "%__quest__%"=="j" set __quest__=Y
if "%__quest__%"=="J" set __quest__=Y
if not "%__quest__%"=="Y" goto end

echo. >> %__textfile__%
echo ### THIS IS A COPY FROM THE MAIL TO %__to__% ### >> %__textfile__%
set __to__=%__from__%
set __cc__=
call :create_mail
%__sendmail__% < %__tempfile__%

goto end

:create_mail
cls
echo ### create the mail ###
ECHO From: %__from__% > %__tempfile__%
ECHO To: %__to__% >> %__tempfile__%
ECHO Cc: %__cc__% >> %__tempfile__%
ECHO Subject: %__subject__% >> %__tempfile__%
type %__textfile__% >> %__tempfile__%

echo.
echo following mail will be send
echo.
type %__tempfile__%
echo.
goto :EOF


:end
DEL %__tempfile__%